' ----------------------------------------------------------
' Script de suppression des fichiers DESKTOP.INI des dossiers
'    %ALLUSERSPROFILE%\Menu Démarrer\
'    %ALLUSERSPROFILE%\Menu Démarrer\Programmes\
'    %ALLUSERSPROFILE%\Menu Démarrer\Programmes\Démarrage
' contenant les lignes
'    [.ShellClassInfo]
'    LocalizedResourceName=@%SystemRoot%\system32\shell32.dll,-21787
' qui provoquent au démrrage l'ouverture du bloc-notes sous Windows XP 
'
' JC BELLAMY © 2004
' ----------------------------------------------------------
ForReading=1
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
Set Shell = Wscript.CreateObject("WScript.Shell")
Set fldrs = Shell.SpecialFolders
Fd=array("AllUsersStartMenu","AllUsersPrograms","AllUsersStartup")
Test="[.ShellClassInfo]" & VBCRLF & "LocalizedResourceName=@%SystemRoot%\system32\shell32.dll,-21787"
nf=0
msg=""
For i = lbound(Fd) To Ubound(Fd)
	Desktopini=fldrs(Fd(i)) & "\desktop.ini"
	If fso.FileExists(Desktopini) Then
		set ts=fso.OpenTextFile(Desktopini, ForReading)
		buffer=ts.ReadAll
		ts.Close
		If InStr(1,buffer,Test,vbTextCompare)>0 Then
			nf=nf+1
			msg=msg & "Suppression du fichier" & vbcrlf & Desktopini & vbcrlf & vbcrlf
			fso.DeleteFile Desktopini,true 
			End If
		End If
	Next
If nf=0 Then
	msg="Aucun fichier DESKTOP.INI défectueux n'a été trouvé" 
Else
	msg=msg & nf & " fichier(s) DESKTOP.INI supprimé(s)"
	End If
wscript.echo msg