' ----------------------------------------------------------
' Script d'ajout/suppression de ports TCP et UDP
' dans le coupe-feu de Windows XP
'
' JC BELLAMY © 2004
' ----------------------------------------------------------
<job>
<runtime>
<description  author="jcb">
Ce script permet d'ajouter ou supprimer des ports TCP et UDP
dans la configuration du coupe-feu de Windows XP
JCB © 2004
--------------------------------------------------------
</description>
<named 
	name = "card" 
	helpstring = "Nom de la carte réseau
        (si vide, affichage de la liste des cartes)" 
	type = "string" 
	required = "true" />
<named 
	name = "ports" 
	helpstring = "Liste des ports TCP ou UDP à ajouter ou supprimer
         (si vide, affichage de la liste des ports actuels)
         Chaque n° de port doit être précédé de :
           + (ajout du port) ou - (suppression du port)
           T (TCP) ou U (UDP)
         Les ports doivent être séparés par des virgules ou espaces" 		  
	type = "string" 
	required = "false" />
<named
	name = "action"
	helpstring = "Action sur le coupe-feu : 
           START : (re)démarrage (valeur par défaut)
           STOP  : arrêt"        
	type = "string" 
	required = "false" />
<example>
Exemples: 
  ICFports.wsf /card:LAN /ports:"+T139 +T445 +U137 +U138 +U445"
    ajoute sur la carte "LAN" les ports TCP 139,445 et UDP 137,138,448
    (partage de fichiers et imprimantes)
  ICFports.wsf /card:"Connexion 1394" /ports:"-T443 -T563"
    supprime sur la carte "Connexion 1394" les ports TCP 443 et 563 
    (AOL Instant Messenger)   
  ICFports.wsf /card:LAN /ports:	
    affiche la liste ports autorisés sur la carte "LAN"
  ICFports.wsf /card:LAN /action:STOP	
    arrête le coupe-feu sur la carte "LAN"
  ICFports.wsf /card:
    affiche la liste des cartes réseau
</example>
</runtime>
<script language="VBScript">
'--------------------------------------------------------------------
const ICSSC_DEFAULT   = 0
const ICSTT_NAME      = 0
const ICSTT_IPADDRESS = 1
const NCM_SHAREDACCESSHOST_LAN = 8
const NCM_SHAREDACCESSHOST_RAS = 9
const NAT_PROTOCOL_TCP = 6
const NAT_PROTOCOL_UDP = 17
const NCCF_SHARED     = &H0100   ' Connexion partagée
const NCCF_FIREWALLED = &H0400   ' Connexion protégée

Set args  = Wscript.Arguments
Set shell = WScript.CreateObject("WScript.Shell")
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
Set net   = Wscript.CreateObject("WScript.Network")

nbargs=args.count
If nbargs=0 Then
	WScript.Arguments.ShowUsage
	WScript.Quit
	End If

KeyVer="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName"
OKscript=false
on error resume next
PN=shell.RegRead(keyver)
if err.number=0 then
	If PN="Microsoft Windows XP" Then OKscript=true
	End If
on error goto 0
If not OKscript Then
	wscript.echo "Ce script ne concerne que Windows XP !"
	wscript.quit
	End If

Set Named   = WScript.Arguments.Named
If not named.Exists("card") Then 
	WScript.Arguments.ShowUsage
	WScript.Quit
	End If
curcard=named.Item("card")
curports=named.Item("ports")
action=ucase(named.Item("action"))
NewState=true
If action="STOP" Then NewState=false

computer=Ucase(net.ComputerName)

on error resume next
set objShare = wscript.CreateObject("HNetCfg.HNetShare.1")
if not IsObject(objShare) then
	WScript.Echo "Erreur d'accès à HNetCfg.HNetShare"
	wscript.quit
	End If
set objEveryColl = objShare.EnumEveryConnection
if not IsObject(objEveryColl) then 
	WScript.Echo "Erreur dans l'énumération des connexions"
	wscript.quit
	End If

'===== Liste des cartes
If curcard="" Then
	str="Liste des cartes réseau de " & Computer & " et état du coupe-feu :"
	For each objNetConn in objEveryColl
		set objShareCfg = objShare.INetSharingConfigurationForINetConnection(objNetConn)
		If IsObject(objShareCfg) Then
			set objNCProps = objShare.NetConnectionProps(objNetConn)
			str = str & VBCRLF & "  " & objNCProps.Name & " (" & StrState(objShareCfg.InternetFirewallEnabled) & ")"
			end if
		next
	wscript.echo str
	wscript.quit
	End If

'===== Examen d'une carte donnée 
CardFound=false
For each objNetConn in objEveryColl
	set objShareCfg = objShare.INetSharingConfigurationForINetConnection(objNetConn)
	If IsObject(objShareCfg) Then
		set objNCProps = objShare.NetConnectionProps(objNetConn)
		card=objNCProps.Name
		If Ucase(card)=Ucase(curcard) Then
			CardFound=true
			exit for
			End If
		End if
	next
If not CardFound Then
	wscript.echo "Carte " & curcard & " non trouvée"
	wscript.quit
	End If

OldState=objShareCfg.InternetFirewallEnabled
wscript.echo "Le coupe-feu est " & StrState(OldState) & " sur " & card
If NewState<>OldState Then
	If NewState Then
		objShareCfg.EnableInternetFirewall
		wscript.echo "Démarrage du coupe-feu"
	Else
		objShareCfg.DisableInternetFirewall
		wscript.echo "Arrêt du coupe-feu"
		wscript.quit
		End If
	End If

'===== Affichage des ports autorisés 
If Curports="" Then
	dim tabport()
	set objPMColl = objShareCfg.EnumPortMappings(ICSSC_DEFAULT)
	str="Liste des ports autorisés sur la carte " & curcard & " de " & Computer & " : "
	np=0
	For each objPortMapping in objPMColl
		np=np+1
		redim preserve tabport(np)
		set objPMProps = objPortMapping.Properties		
		tabport(np)=ProtoLongName(objPMProps.IPProtocol) & " " _
			& FormatStrR(objPMProps.InternalPort,5) & " -> " _
			& FormatStrR(objPMProps.ExternalPort,5) & " : " _
			& objPMProps.Name
		next
	For i = np-1 to 1 step -1
		For j= i To np-1
			r=StrComp(tabport(j),tabport(j+1),vbTextCompare)
			If r>0 Then
				buffer=tabport(j)
				tabport(j)=tabport(j+1)
				tabport(j+1)=buffer
				End If
			Next
		Next
	For i = 1 To np
		str = str & VBCRLF & tabport(i)  
		Next
	wscript.echo str
	wscript.quit
	End If

'===== Modification des ports
CurPorts=Replace(Curports,","," ")
While InStr(CurPorts,"  ")>0
	CurPorts=Replace(Curports,"  "," ")
	Wend
TabP=Split(CurPorts," ")
Np=Ubound(TabP)

'===== Suppression
For i = 0 To Np
	If left(TabP(i),1)="-" Then
		StrProt=ucase(mid(TabP(i),2))
		ExistProto=false
		set objPMColl = objShareCfg.EnumPortMappings(ICSSC_DEFAULT)
		For each objPortMapping in objPMColl
			set objPMProps = objPortMapping.Properties
			CurProt=ProtoShortName(objPMProps.IPProtocol) & objPMProps.ExternalPort 	
			If CurProt=StrProt Then
				objPortMapping.Delete
				wscript.echo "Suppression du port " & ProtoLongName(objPMProps.IPProtocol) & " " & objPMProps.ExternalPort
				ExistProto=true
				exit for
				End If
			next
		If not ExistProto Then 
			Proto=GetProto(StrProt)
			wscript.echo "Le port " & ProtoLongName(Proto) & " " & mid(StrProt,2) & " n'existe pas"
			end if
		End If
	next

'===== Ajout
For i = 0 To Np
	If left(TabP(i),1)="+" Then
		StrProt=ucase(mid(TabP(i),2))
		ExistProto=false
		set objPMColl = objShareCfg.EnumPortMappings(ICSSC_DEFAULT)
		For each objPortMapping in objPMColl
			set objPMProps = objPortMapping.Properties
			CurProt=ProtoShortName(objPMProps.IPProtocol) & objPMProps.ExternalPort 	
			If CurProt=StrProt Then
				If objPMProps.Enabled Then
					wscript.echo "Le port " & ProtoLongName(objPMProps.IPProtocol) & " " & objPMProps.ExternalPort & " existe déjà"
				Else
					objPortMapping.Enable
					wscript.echo "Activation du port " & ProtoLongName(objPMProps.IPProtocol) & " " & objPMProps.ExternalPort
					End If
				ExistProto=true
				exit for
				End If
			next
		If not ExistProto Then
			Proto=GetProto(StrProt)
			ExtPort=mid(StrProt,2)
			If Proto<>0 and IsNumeric(ExtPort) Then
				IntPort=ExtPort
				Options=0
				PortName=ProtoLongName(Proto) & " " & ExtPort
				set objPortMapping = objShareCfg.AddPortMapping(PortName,Proto,ExtPort,IntPort,Options,Computer,ICSTT_NAME)
				objPortMapping.Enable
				wscript.echo "Ajout du port " & PortName
				End If	
			End If	
		End If
	next
wscript.quit
'--------------------------------------------------------------------
Function FormatStrL(ch,lmax)
l=len(ch)
If l<lmax Then 
	For k = l+1 To lmax
		ch=ch & " "
		Next
	End If
FormatStrL=ch
End Function
'--------------------------------------------------------------------
Function FormatStrR(ch,lmax)
l=len(ch)
If l<lmax Then 
	For k = l+1 To lmax
		ch=" " & ch
		Next
	End If
FormatStrR=ch
End Function
'--------------------------------------------------------------------
Function ProtoLongName(Proto)
Select Case Proto
	Case NAT_PROTOCOL_TCP
		ProtoLongName="TCP"
	Case NAT_PROTOCOL_UDP 
		ProtoLongName="UDP"
	Case else
		ProtoLongName="???"
	End Select
End Function
'--------------------------------------------------------------------
Function ProtoShortName(Proto)
Select Case Proto
	Case NAT_PROTOCOL_TCP
		ProtoShortName="T"
	Case NAT_PROTOCOL_UDP 
		ProtoShortName="U"
	Case else
		ProtoShortName="?"
	End Select
End Function
'--------------------------------------------------------------------
Function StrState(Etat)
if Etat then StrState="démarré" else StrState="arrêté"
End Function
'--------------------------------------------------------------------
Function GetProto(Str)
Select Case Ucase(left(Str,1))
	Case "T"
		GetProto=NAT_PROTOCOL_TCP
	Case "U"
		GetProto=NAT_PROTOCOL_UDP
	Case else
		GetProto=0
	End Select
End Function
'--------------------------------------------------------------------
</script>
</job>