' ----------------------------------------------------------
' Script de récupération du SID d'un compte utilisateur
'
' JC BELLAMY © 2004
' ----------------------------------------------------------
<job>
<runtime>
<description  author="jcb">
Ce script permet de récupérer le SID d'un compte utilisateur
d'un ordinateur local ou distant.
JCB © 2004
--------------------------------------------------------
</description>
<named name = "comp" helpstring = "Nom de l'ordinateur (si vide, ordinateur local)" type = "string" required = "false" />
<named name = "user" helpstring = "Nom de l'utilisateur (si vide, affichage de la liste des comptes)" type = "string" required = "false" />
<named name = "?" helpstring = "Affiche la présente aide" type = "string" required = "false" />
<example>
Exemples: 
  name2sid.wsf /comp:SPRINGFIELD
	affiche la liste des comptes et SID de l'ordinateur "SPRINGFIELD"
  name2sid.wsf /user:Homer
	affiche le SID du compte "Homer" sur l'ordinateur local	
  name2sid.wsf /comp:BINGERVILLE /user:Bart
	affiche le SID du compte "Bart" sur l'ordinateur "BINGERVILLE"
</example>
</runtime>
<script language="VBScript">
Const SW_SHOWNORMAL=1 
Set shell = WScript.CreateObject("WScript.Shell")
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
Set net   = Wscript.CreateObject("WScript.Network")
set args=wscript.arguments
nbargs=args.count

TestHost false

Set Named   = WScript.Arguments.Named
Set UnNamed = WScript.Arguments.UnNamed
If named.Exists("?") Then
	WScript.Arguments.ShowUsage
	WScript.Quit
	End If

If named.Exists("comp") Then
	computer=named.Item("comp")
Else
	computer=net.ComputerName
	End If
computer=uCase(computer)

If named.Exists("user") Then
	user=lcase(named.Item("user"))
Else
	user=""
	End If

objWMI="winmgmts:\\" & Computer & "\root\cimv2"
Set objWMIService = GetObject(objWMI)
Query="Select * from Win32_AccountSID"
Set colItems = objWMIService.ExecQuery(Query,,48)
trouve=false
For Each objItem in colItems
	set Account=getobject("winmgmts:" & objItem.Element)
	If user="" Then
		Wscript.Echo "Name   : " & Account.Name
		Wscript.Echo "SID    : " & Account.SID 
		Wscript.Echo
	Else
		If user=lcase(Account.Name) Then
			Wscript.Echo Account.SID
			trouve=true
			exit for
			End If
		End If	
	Next
If user<>"" and not trouve Then Wscript.Echo "Compte " & user & " inexistant"
'--------------------------------------------------------------------
'Sous-programme de test du moteur
'Vu les sorties générées, c'est CSCRIPT (et non pas WSCRIPT)
'qui doit être utilisé de préférence
Sub TestHost(force)
dim rep
strappli=lcase(Wscript.ScriptFullName)
strFullName =lcase(WScript.FullName)
i=InStr(1,strFullName,".exe",1)
j=InStrRev(strFullName,"\",i,1)
strCommand=Mid(strFullName,j+1,i-j-1)
if strCommand<>"cscript" then
	If force then 
		Init="Ce script doit être lancé avec CSCRIPT"
	Else
		Init="Il est préférable de lancer ce script avec CSCRIPT"
		End If
	rep=MsgBox(Init & VBCRLF & _
	"Cela peut être rendu permanent avec la commande" & VBCRLF & _
	"cscript //H:CScript //S /Nologo" & VBCRLF & _
	"Voulez-vous que ce soit fait automatiquement?", _
	vbYesNo + vbQuestion,strappli)
	if rep=vbYes  then 
		nomcmd="setscript.bat"
		Set ficcmd = fso.CreateTextFile(nomcmd)
		ficcmd.writeline "@echo off"
		ficcmd.writeline "cscript //H:CScript //S /Nologo"
		ficcmd.writeline "pause"
		params=""
		For i = 0 To nbargs-1 
			params=params & " " & args(i)
			next
		ficcmd.writeline chr(34) & strappli & chr(34) & params
		ficcmd.writeline "pause"
		ficcmd.close
		shell.Run nomcmd, SW_SHOWNORMAL,true
		force=true
		end if
    If force then WScript.Quit
	end if
end sub
'--------------------------------------------------------------------
</script>
</job>