' ==========================================================
' Création de sous-répertoire à partir du menu contextuel
' (dossiers ou fichiers)
' Auto-installable (par exécution sans paramètres)
' JC BELLAMY © 2001
' ==========================================================
Dim shell, args, fso
Set args  = Wscript.Arguments
Set shell = WScript.CreateObject("WScript.Shell")
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
If args.count=0 Then 
' Auto-installation
	Script=Wscript.ScriptFullName
	register "Drive"
	register "Folder"
	register "Directory"
	register "File"
	MsgBox "Script "& Script &" installé", vbInformation, "Nouveau dossier"
	wscript.quit
	end if
curdir=args(0)
If not fso.FolderExists(curdir)  Then
' On a sélectionné un fichier
	If fso.FileExists(curdir) Then
' On extrait son répertoire
		curdir=fso.GetParentFolderName(curdir)
	else wscript.quit
	    End If 
	End If
subdir=InputBox("Nom du sous-répertoire à créer :",curdir, "Nouveau dossier")
If len(subdir)=0 Then wscript.quit
newdir=fso.BuildPath(curdir,subdir)
If  fso.FolderExists(newdir) Then 
	MsgBox newdir & " existe déjà", vbExclamation, "Nouveau dossier"
	wscript.quit
	end if
fso.CreateFolder(newdir)
MsgBox newdir & " créé", vbInformation, "Nouveau dossier"
WScript.quit

' -----------------------------------------
Sub register(typefic)
Key="HKEY_CLASSES_ROOT\" & typefic &"\shell\newfolder\"
shell.RegWrite Key,"Nouveau sous-répertoire"
Command="wscript """ & Script & """ ""%1"""
shell.RegWrite Key & "command\",Command
End Sub
' -----------------------------------------